IVergara - Final project prototype

 Productivity pal

This project is a small productivity device that uses RFID tags to trigger different modes on a screen. The idea is to make the interaction feel more physical and intentional: instead of opening features through regular buttons or menus, the user taps a specific tag to launch a mode. One mode is a focus timer for work sessions, and another is an active break mode where the user selects a short exercise and follows a countdown on screen.

I originally started the project with an ESP32, but I ran into technical issues while testing the display, which made development less reliable. Another factor was speed: every change on the ESP32 took noticeably longer to compile and upload, which slowed down testing and experimentation. Because of that, I moved the project to an Arduino Uno. The Uno felt easier to work with for this prototype because uploads were much faster and the overall setup was simpler to debug.

The device combines a display, an RFID reader, and a rotary encoder. The RFID reader and the screen share some communication pins, which keeps the wiring compact, while separate control pins let each part work correctly in the same system. The encoder is used to move through options and confirm selections, so once a mode is opened, the user can interact with it in a simple and clear way.

 Video

 

 

 

 Photos

 Schematic

 

 

Code 

#include <Adafruit_GFX.h>

#include <Adafruit_ST7789.h>

#include <SPI.h>

#include <MFRC522.h>

#define TFT_CS    10

#define TFT_DC    8

#define TFT_RST   9

#define RFID_SS   7

#define RFID_RST  2

const int pinA = 3;

const int pinB = 4;

const int pushPin = 5;

const int k0Pin = 6;

int currentMode = 0;  

Adafruit_ST7789 tft = Adafruit_ST7789(TFT_CS, TFT_DC, TFT_RST);

MFRC522 rfid(RFID_SS, RFID_RST);

String lastUID = "";

int lastAState;

bool lastButtonState = HIGH;

// Work mode options

int timerOptions[3] = {5, 10, 20};

int selectedIndex = 0;

bool workTimerStarted = false;

unsigned long workStartTime = 0;

unsigned long workDuration = 0;

int lastWorkSecond = -1;

// Break Mode options

String breakOptions[3] = {"Stretch", "Jumping Jacks", "Pushups"};

int breakSelectedIndex = 0;

bool breakTimerStarted = false;

unsigned long breakStartTime = 0;

const unsigned long breakDuration = 2UL * 60UL * 1000UL;

int lastBreakSecond = -1;

// Home screen

void runHomeMode() {

  tft.fillScreen(ST77XX_BLACK);

  tft.setTextSize(2);

  tft.setTextColor(ST77XX_GREEN);

  tft.setCursor(20, 20);

  tft.println("Home");

  tft.setTextSize(1);

  tft.setCursor(20, 60);

  tft.println("Tap an RFID tag");

  tft.setCursor(20, 80);

  tft.println("Blue tag -> Work");

  tft.setCursor(20, 95);

  tft.println("Card -> Break");

}

// Work screen

void drawWorkSelectionScreen() {

  tft.fillScreen(ST77XX_BLACK);

  tft.setTextSize(2);

  tft.setTextColor(ST77XX_YELLOW);

  tft.setCursor(20, 20);

  tft.println("Work Mode");

  tft.setTextSize(1);

  tft.setTextColor(ST77XX_WHITE);

  tft.setCursor(20, 50);

  tft.println("Choose timer:");

  for (int i = 0; i < 3; i++) {

    int y = 80 + i * 25;

    if (i == selectedIndex) {

      tft.fillRect(20, y - 2, 140, 18, ST77XX_YELLOW);

      tft.setTextColor(ST77XX_BLACK);

    } else {

      tft.fillRect(20, y - 2, 140, 18, ST77XX_BLACK);

      tft.setTextColor(ST77XX_WHITE);

    }

    tft.setTextSize(2);

    tft.setCursor(30, y);

    tft.print(timerOptions[i]);

    tft.print(" min");

  }

  tft.setTextSize(1);

  tft.setTextColor(ST77XX_CYAN);

  tft.setCursor(20, 170);

  tft.println("Press knob to start");

}

void enterWorkMode() {

  workTimerStarted = false;

  selectedIndex = 0;

  lastWorkSecond = -1;

  drawWorkSelectionScreen();

}

void drawWorkTimerScreen() {

  tft.fillScreen(ST77XX_BLACK);

  tft.setTextSize(2);

  tft.setTextColor(ST77XX_YELLOW);

  tft.setCursor(20, 20);

  tft.println("Work Mode");

  tft.setTextSize(1);

  tft.setTextColor(ST77XX_WHITE);

  tft.setCursor(20, 50);

  tft.print("Pomodoro ");

  tft.print(timerOptions[selectedIndex]);

  tft.println(" min");

}

void startWorkTimer() {

  workTimerStarted = true;

  workStartTime = millis();

  workDuration = (unsigned long)timerOptions[selectedIndex] * 60UL * 1000UL;

  lastWorkSecond = -1;

  drawWorkTimerScreen();

}

void runWorkMode() {

  if (!workTimerStarted) {

    int currentAState = digitalRead(pinA);

    if (currentAState != lastAState) {

      if (digitalRead(pinB) != currentAState) {

        selectedIndex++;

      } else {

        selectedIndex--;

      }

      if (selectedIndex > 2) selectedIndex = 0;

      if (selectedIndex < 0) selectedIndex = 2;

      drawWorkSelectionScreen();

      delay(5);

    }

    lastAState = currentAState;

    bool currentButtonState = digitalRead(pushPin);

    if (currentButtonState == LOW && lastButtonState == HIGH) {

      startWorkTimer();

      delay(200);

    }

    lastButtonState = currentButtonState;

  } else {

    unsigned long elapsed = millis() - workStartTime;

    if (elapsed > workDuration) {

      elapsed = workDuration;

    }

    int remainingSeconds = (workDuration - elapsed) / 1000;

    int minutes = remainingSeconds / 60;

    int seconds = remainingSeconds % 60;

    if (remainingSeconds != lastWorkSecond) {

      lastWorkSecond = remainingSeconds;

      char timeText[6];

      sprintf(timeText, "%02d:%02d", minutes, seconds);

      tft.fillRect(20, 80, 160, 40, ST77XX_BLACK);

      tft.setTextSize(3);

      tft.setTextColor(ST77XX_RED);

      tft.setCursor(20, 80);

      tft.print(timeText);

      if (remainingSeconds == 0) {

        tft.fillRect(20, 140, 140, 30, ST77XX_BLACK);

        tft.setTextSize(2);

        tft.setTextColor(ST77XX_GREEN);

        tft.setCursor(20, 140);

        tft.println("Done");

      }

    }

  }

}

// Break screen

void drawBreakSelectionScreen() {

  tft.fillScreen(ST77XX_BLACK);

  tft.setTextSize(2);

  tft.setTextColor(ST77XX_CYAN);

  tft.setCursor(20, 20);

  tft.println("Break Mode");

  tft.setTextSize(1);

  tft.setTextColor(ST77XX_WHITE);

  tft.setCursor(20, 50);

  tft.println("Choose exercise:");

  for (int i = 0; i < 3; i++) {

    int y = 80 + i * 25;

    if (i == breakSelectedIndex) {

      tft.fillRect(20, y - 2, 180, 18, ST77XX_CYAN);

      tft.setTextColor(ST77XX_BLACK);

    } else {

      tft.fillRect(20, y - 2, 180, 18, ST77XX_BLACK);

      tft.setTextColor(ST77XX_WHITE);

    }

    tft.setTextSize(1);

    tft.setCursor(30, y);

    tft.print(breakOptions[i]);

  }

  tft.setTextSize(1);

  tft.setTextColor(ST77XX_YELLOW);

  tft.setCursor(20, 170);

  tft.println("Press knob to start");

}

void enterBreakMode() {

  breakTimerStarted = false;

  breakSelectedIndex = 0;

  lastBreakSecond = -1;

  drawBreakSelectionScreen();

}

void drawBreakTimerScreen() {

  tft.fillScreen(ST77XX_BLACK);

  tft.setTextSize(2);

  tft.setTextColor(ST77XX_CYAN);

  tft.setCursor(20, 20);

  tft.println("Break Mode");

  tft.setTextSize(1);

  tft.setTextColor(ST77XX_WHITE);

  tft.setCursor(20, 50);

  tft.print("Exercise: ");

  tft.println(breakOptions[breakSelectedIndex]);

}

void startBreakTimer() {

  breakTimerStarted = true;

  breakStartTime = millis();

  lastBreakSecond = -1;

  drawBreakTimerScreen();

}

void runBreakMode() {

  if (!breakTimerStarted) {

    int currentAState = digitalRead(pinA);

    if (currentAState != lastAState) {

      if (digitalRead(pinB) != currentAState) {

        breakSelectedIndex++;

      } else {

        breakSelectedIndex--;

      }

      if (breakSelectedIndex > 2) breakSelectedIndex = 0;

      if (breakSelectedIndex < 0) breakSelectedIndex = 2;

      drawBreakSelectionScreen();

      delay(5);

    }

    lastAState = currentAState;

    bool currentButtonState = digitalRead(pushPin);

    if (currentButtonState == LOW && lastButtonState == HIGH) {

      startBreakTimer();

      delay(200);

    }

    lastButtonState = currentButtonState;

  } else {

    unsigned long elapsed = millis() - breakStartTime;

    if (elapsed > breakDuration) {

      elapsed = breakDuration;

    }

    int remainingSeconds = (breakDuration - elapsed) / 1000;

    int minutes = remainingSeconds / 60;

    int seconds = remainingSeconds % 60;

    if (remainingSeconds != lastBreakSecond) {

      lastBreakSecond = remainingSeconds;

      char timeText[6];

      sprintf(timeText, "%02d:%02d", minutes, seconds);

      tft.fillRect(20, 85, 160, 40, ST77XX_BLACK);

      tft.setTextSize(3);

      tft.setTextColor(ST77XX_GREEN);

      tft.setCursor(20, 85);

      tft.print(timeText);

      if (remainingSeconds == 0) {

        tft.fillRect(20, 140, 220, 50, ST77XX_BLACK);

        tft.setTextSize(2);

        tft.setTextColor(ST77XX_YELLOW);

        tft.setCursor(20, 140);

        tft.println("Congrats on");

        tft.setCursor(20, 165);

        tft.println("staying active");

      }

    }

  }

}

void setup() {

  Serial.begin(9600);

  delay(2000);

  pinMode(pinA, INPUT_PULLUP);

  pinMode(pinB, INPUT_PULLUP);

  pinMode(pushPin, INPUT_PULLUP);

  pinMode(k0Pin, INPUT_PULLUP);

  SPI.begin();

  tft.init(240, 320);

  tft.invertDisplay(false);

  tft.setRotation(1);

  rfid.PCD_Init();

  lastAState = digitalRead(pinA);

  runHomeMode();

}

void loop() {

  if (rfid.PICC_IsNewCardPresent() && rfid.PICC_ReadCardSerial()) {

    String uidString = "";

    for (byte i = 0; i < rfid.uid.size; i++) {

      if (rfid.uid.uidByte[i] < 0x10) {

        uidString += "0";

      }

      uidString += String(rfid.uid.uidByte[i], HEX);

      if (i < rfid.uid.size - 1) {

        uidString += " ";

      }

    }

    uidString.toUpperCase();

    lastUID = uidString;

    Serial.print("UID: ");

    Serial.println(lastUID);

    rfid.PICC_HaltA();

    rfid.PCD_StopCrypto1();

    if (lastUID == "13 EA 00 2D") {

      currentMode = 1;

      lastAState = digitalRead(pinA);

      lastButtonState = HIGH;

      enterWorkMode();

    }

    else if (lastUID == "8C 50 FA 03") {

      currentMode = 2;

      lastAState = digitalRead(pinA);

      lastButtonState = HIGH;

      enterBreakMode();

    }

    else {

      currentMode = 0;

      runHomeMode();

    }

  }

  if (digitalRead(k0Pin) == LOW) {

    currentMode = 0;

    runHomeMode();

    delay(200);

  }

  if (currentMode == 1) {

    runWorkMode();

  }

  else if (currentMode == 2) {

    runBreakMode();

  }

  delay(50);

}

 

30 March 2026 Prototype Review - Team 6

Our prototype is a two-handed flat-panel cardboard controller designed for Star Wars: Squadrons, built to put the player in the feeling of actually piloting a starfighter. The CPE sits at the center of the controller, and its built-in accelerometer handles left and right steering by tilting the whole controller side to side, no joystick needed. Thrust is handled by a thumbstick that controls forward and backward speed. We have four external buttons. Two handle primary fire, secondary fire, and the ones in the circuit playground buttons handle toggle targeting, and ship repair, while a switch on the right side activates sublight boost for a quick speed burst. During prototyping we learned that the potentiometers we originally planned for laser power and shield routing couldn't map cleanly to the in-game scroll wheel inputs the CPE can't replicate, so we cut them. The front/back shield transfer switch was also dropped for the same reason. In the final version we want to revisit those inputs with a different approach.

Peer Review Questions: What other controller styles or inputs do you think would work well for a space combat simulation like this? What do you think is the coolest part of the design so far?

Prototype Review - Team 17

Our prototype is a controller modeled after a stun gun inspired by Resident Evil. The idea is to make the gameplay feel more physical and tense by using a mix of buttons and sensors instead of a normal controller. Movement and navigation are a bit more limited and take more intentional input, which fits the slower pace of the game. Things like aiming, attacking, and interacting use less common inputs like light and sound, so the player has to actually pay attention instead of just pressing buttons automatically. Other actions like running, quick turning, and opening the inventory are tied to different physical interactions to make everything feel more hands on.

This is the link to the video:

https://youtu.be/P7Iy3l_Gb6s 

What are some ways we could add more natural human gestures into the controller to make it feel more physical and realistic?

Are any of the controls confusing or too complicated to use during gameplay, and if so, which ones might be better if we simplified or changed them? 

Team 3 Scaffolding Prototype

 For this prototype, we created a low-fidelity Minecraft pickaxe controller using cardboard, clear tape, and glue. The goal was to make a controller that physically matches the main tool used in the game, so the interaction feels more immersive and connected to gameplay.

Buttons are placed along the handle of the pickaxe, allowing the user to hold it like a real tool while pressing inputs. Swinging or tapping the pickaxe onto a surface triggers actions like mining, while hitting the bottom of the handle is used for jumping. I also experimented with dragging the pickaxe across a surface while holding a button to simulate camera movement.

Prototype Review - Team 11

 

Sonic Robo Blast 2

We are building the ‘SRB2 Kart Radio.’ Instead of a standard steering wheel, it’s a car radio. The idea is built on the irony that the user is ‘distracted driving’ by ‘playing’ with the radio. It’s a joke about how playing with a radio is a part of the fun, especially in a racing videogame where the music a massive part of the vibe.

Mechanically, the ‘Volume’ knob is mapped to the player speed and the ‘Tuning’ knob to the steering. A slide potentiometer is used to control the item usage and drift. By actually sliding the potentiometer, it feels like you are forcing the kart sideways, making it a satisfying experience. The middle zones for all 3 analog inputs are currently neutral zones to help clearly distinguish between states.

(3D Printed Shell Prototype)

(Circuit Prototype)

Team 8 Prototype Review

Our prototype is designed like a map for the game Hidden Folks (think of it like iSpy). Since you want to find people or things within the levels, a map made sense as a design choice as a map leads you to the treasure, or in this case, the hidden folks. You can tilt it to move around the level, the pressure pad arrows are used for moving the mouse on where you was to click, the potentiometer zooms in/out, and the light sensor X confirms a click with the mouse.

Questions: How could our design or layout of the controller be improved? Do you think we are missing anything?

Pics:

Video: To Be Added

Scaffolding: Prototype Review - Team 1

Our prototype controller is for the GBA port of the arcade game Mario Bros. We decided to focus on the plumbing and pipe aspect of the game, allowing players to connect to the role of the characters and the game world. The main design is a large curved pipe, with a turning water valve, hex nuts, and a POW block on top. Players will control the aspects of the pipe to influence the game mechanics. The valve wheel is connected to a potentiometer that controls the player’s left and right movement, while a second potentiometer controls the player’s jumping and crouching, turned by a wrench. A sound sensor is hidden in the POW block that will pause the game. Clicking the POW block on the top of the controller will instead toggle the running movement of the game. All of these aspects aim to immerse the player and satisfy them from a artistic and gameplay standpoint.

Feedback Prompts:

Would you rather have the wrench as a separate piece or a fixed attachment?

Would you want to use the crouch control in the game?

Internal:

Prototype Review - Team 22

 

For our game, we picked "Sort the Court". In the game, you play as a ruler and respond either yes

or no to your subject's requests. Our controller is a crown that allows the player to physically

respond with either yes or no. It works by utilizing the accelerometer inside the Circuit

Playground Express to detect motion where a nod up and down will get a yes response and a nod

side to side will get a no response. There is a potentiometer on the side of the crown that acts as

an on and off switch so that the player can remove the controller without accidentally progressing

the game.

Questions for Classmates:

Does the controller seem inconvenient to use in any way, shape, or form?

Are there any recommendations on if the power switch can be integrated into the shape

of the crown better?